SKU:RB-01C016 Arduino 网络扩展板

来自ALSROBOT WiKi
跳转至: 导航搜索
RB-01C016.jpg

目录

产品概述

以W5100为核心的Arduino Ethernet网络扩展模块,可以使Arduino成为简单的Web服务器或者通过网络控制读写Arduino的数字和模拟接口等网络应用。可直接使用IDE中的Ethernet库文件便可实现一个简单Web服务器。同时该版本的支持mini SD卡(TF卡)读写,功能强悍,不容错过!该扩展板采用了可堆叠的设计,可直接插到Arduino上,同时我们的其他扩展板也可以插上去。

规格参数

W5100特性

  1. 支持SPI接口(SCS、SCLK、MISO、MOSI),接线方便,程序简单;
  2. 支持硬件TCP/IP协议栈,支持TCP,UDP,ICMP,IGMP,IPv4,ARP,PPPoE.
  3. 内嵌10BaseT/100BaseTX以太网物理层;
  4. 支持自动通信握手(全双工和半双工);
  5. 端口支持3种工作模式(客户端、服务端、UDP);
  6. 支持4个独立端口同时运行;
  7. 内部集成16KBYTE收发缓存;
  8. 支持自动极性转换(DMI/MDIX);

W5100优势

  1. W5100硬件集成TCP/IP协议栈、MAC、PHY,减少了用户代码量、减轻了CPU的压力,而相对便宜的ENC28J60只集成MAC和PHY,TCP/IP协议栈须要用户在上层代码中实现;
  2. W5100可以通过SPI接口控制,只须要操作少量的寄存器即可,大量节约了开发时间.
  3. W5100是通过SPI发指令、数据操作寄存器,不同平台移植W5100的程序更加方便、简单;

使用方法

接线方法

1.将网络扩展板与UNO插接在一起,确保引脚连接正常。

Wangluokuozhan1.jpg

2.如图所示连接UNO和PC机,下载代码到UNO控制器中

Wangluokuozhan2.jpg

例子程序

/*
  Web Server
 
 A simple web server that shows the value of the analog input pins.
 using an Arduino Wiznet Ethernet shield. 
 
 Circuit:
 * Ethernet shield attached to pins 10, 11, 12, 13
 * Analog inputs attached to pins A0 through A5 (optional)
 
 created 18 Dec 2009
 by David A. Mellis
 modified 9 Apr 2012
 by Tom Igoe
 
 */

#include <SPI.h>
#include <Ethernet.h>

// Enter a MAC address and IP address for your controller below.
// The IP address will be dependent on your local network:
byte mac[] = { 
  0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED };
IPAddress ip(192,168,1,177);

// Initialize the Ethernet server library
// with the IP address and port you want to use 
// (port 80 is default for HTTP):
EthernetServer server(80);

void setup() {
 // Open serial communications and wait for port to open:
  Serial.begin(9600);
   while (!Serial) {
    ; // wait for serial port to connect. Needed for Leonardo only
  }


  // start the Ethernet connection and the server:
  Ethernet.begin(mac, ip);
  server.begin();
  Serial.print("server is at ");
  Serial.println(Ethernet.localIP());
}


void loop() {
  // listen for incoming clients
  EthernetClient client = server.available();
  if (client) {
    Serial.println("new client");
    // an http request ends with a blank line
    boolean currentLineIsBlank = true;
    while (client.connected()) {
      if (client.available()) {
        char c = client.read();
        Serial.write(c);
        // if you've gotten to the end of the line (received a newline
        // character) and the line is blank, the http request has ended,
        // so you can send a reply
        if (c == '\n' && currentLineIsBlank) {
          // send a standard http response header
          client.println("HTTP/1.1 200 OK");
          client.println("Content-Type: text/html");
          client.println("Connection: close");  // the connection will be closed after completion of the response
	  client.println("Refresh: 5");  // refresh the page automatically every 5 sec
          client.println();
          client.println("<!DOCTYPE HTML>");
          client.println("<html>");
          // output the value of each analog input pin
          for (int analogChannel = 0; analogChannel < 6; analogChannel++) {
            int sensorReading = analogRead(analogChannel);
            client.print("analog input ");
            client.print(analogChannel);
            client.print(" is ");
            client.print(sensorReading);
            client.println("<br />");       
          }
          client.println("</html>");
          break;
        }
        if (c == '\n') {
          // you're starting a new line
          currentLineIsBlank = true;
        } 
        else if (c != '\r') {
          // you've gotten a character on the current line
          currentLineIsBlank = false;
        }
      }
    }
    // give the web browser time to receive the data
    delay(1);
    // close the connection:
    client.stop();
    Serial.println("client disonnected");
  }
}

3.将网络扩展板使用网线与电脑连接

Wangluokuozhan3.jpg

4.设置本地计算机的网络

Wangluokuozhan4.jpg

5.设置后W5100网络扩展板板载的4个LED会亮起,如果没有请按下复位按钮

Wangluokuozhan5.jpg

程序效果

1.现在读出W5100网络扩展板的IP地址

Wangluokuozhan6.jpg

2.通过电脑可以访问W5100网络扩展板

Wangluokuozhan7.jpg

其他应用

Arduino Ethernet网络扩展模块与Arduino UNO 控制器

RB-01C0161.jpg

Arduino Ethernet网络扩展模块与Arduino MEGA2560控制器

RB-01C0163.jpg

产品相关推荐

Erweima.png

购买地址

Arduino 网络扩展板

周边产品推荐

Arduino Protoype Shield 原型扩展板
Arduino GSM 扩展板 Arduino Integrated Antenna 官方原装进口

相关问题解答

Arduino 网络扩展板介绍

相关学习资料

奥松机器人技术论坛